Methyl Tert-Butyl Ether (MTBE) Decomposition with a Reactive Distillation Unit

Manipulate[
Module[{sol,x1,y1,x2,y2,x3,y3,x4,y4,V,Dist,L,Lp,Vp,B,Le,rate,G,A,Psat,Keq,kf,T,a,Vm,Rg,Aa,Ba,Ca,xf1,tbl,R,Fa,xf1a,xf2a,xf3a,xf2,xf3,F,s,P},G[i_][p_][t_]:=Exp[1-Log[(∑_(j=1)^3)x[j] A[i,j][p][t]]-(∑_(k=1)^3)(((x[k] A[k,i][p][t])/((∑_(j=1)^3)x[j] A[k,j][p][t])))]/.x[3]->x3[p][t]/.x[1]->x1[p][t]/.x[2]->x2[p][t];
A[i_,j_][p_][t_]:=Vm[j]/Vm[i] Exp[-a[i,j]/(Rg T[p][t])];
a[1,1]=0;
a[1,2]=169.9953;
a[1,3]=-30.2477;
a[2,1]=2576.8532;
a[2,2]=0;
a[2,3]=1483.2478;
a[3,1]=271.5669;
a[3,2]=-406.3902;
a[3,3]=0;
Vm[1]=93.33;
Vm[2]=44.44;
Vm[3]=118.8;
Rg=1.987;P=11 1.013 10^5;
Psat[i_][p_][t_]:=Exp[(Aa[i]+Ba[i]/(T[p][t]+Ca[i]))];
Aa[1]=20.64559;Aa[2]=23.49989;
Aa[3]=20.71616;
Ba[1]=-2125.74886;Ba[2]=-3643.31362;Ba[3]=-2571.58460;
Ca[1]=-33.160;Ca[2]=-33.434;Ca[3]=-48.406;
Keq[i_][t_]:= Exp[16.33-6820/T[i][t]];kf[i_][t_]:=5.358943577430972`*^10 Exp[-(10007./(T[i][t]))];
y1[p_][t_]:=x1[p][t] G[1][p][t] Psat[1][p][t]/P;
y2[p_][t_]:=x2[p][t] G[2][p][t] Psat[2][p][t]/P;
y3[p_][t_]:=x3[p][t] G[3][p][t] Psat[3][p][t]/P;x3[p_][t_]:=1-x1[p][t]-x2[p][t];
rate[i_][t_]:=(G[3][i][t]x3[i][t]-G[1][i][t] G[2][i][t]x1[i][t] x2[i][t]/Keq[i][t]);
xf1a=0.0;xf2a=0.0;xf3a=1.0;Fa=10.0;R=7.25;s=8.24999995;

sol=Quiet[NDSolve[Flatten[{

500 x1[0]'[t]== V[t] y1[1][t]-(L[t]+Dist[t]) x1[0][t],500 x2[0]'[t]== V[t] y2[1][t]-(L[t]+Dist[t]) x2[0][t],
Table[{H x1[i]'[t]== V[t] (y1[i+1][t]-y1[i][t])+L[t]  (x1[i-1][t]- x1[i][t]),H x2[i]'[t]== V[t] (y2[i+1][t]-y2[i][t])+L[t] ( x2[i-1][t]-x2[i][t])},{i,1,5}],

H x1[6]'[t]== V[t] y1[7][t]-V[t]y1[6][t]+L[t]  x1[5][t]-Le[1][t] x1[6][t]+H kf[6][t] rate[6][t],H x2[6]'[t]== V[t] y2[7][t]-V[t]y2[6][t]+L[t]  x2[5][t]-Le[1][t] x2[6][t]+H kf[6][t] rate[6][t],

Le[1][t]== L[t]+H kf[6][t] rate[6][t],

Table[{H x1[i]'[t]== V[t] (y1[i+1][t]-y1[i][t])+Le[i-6][t]  x1[i-1][t]-Le[i-5][t]x1[i][t]+H kf[i][t] rate[i][t]+If[i== 8,Fa xf1a,0],H x2[i]'[t]== V[t] (y2[i+1][t]-y2[i][t])+Le[i-6][t]  x2[i-1][t]-Le[i-5][t]x2[i][t]+H kf[i][t] rate[i][t]+If[i== 8,Fa xf1a,0]},{i,7,11}],

Le[2][t]== Le[1][t]+H kf[7][t] rate[7][t],Le[3][t]== Le[2][t]+H kf[8][t] rate[8][t]+Fa,Le[4][t]== Le[3][t]+H kf[9][t] rate[9][t],Le[5][t]== Le[4][t]+H kf[10][t] rate[10][t],Le[6][t]== Le[5][t]+H kf[11][t] rate[11][t],

Table[{H x1[i]'[t]== V[t] (y1[i+1][t]- y1[i][t])+Le[6][t]( x1[i-1][t]-x1[i][t]),H x2[i]'[t]== V[t] (y2[i+1][t]- y2[i][t])+Le[6][t] ( x2[i-1][t]-x2[i][t])},{i,12,16}],

2000 x1[17]'[t]== Le[6][t] x1[16][t]-(V[t] y1[17][t]+B[t] x1[17][t]),2000 x2[17]'[t]== Le[6][t] x2[16][t]-(V[t] y2[17][t]+B[t] x2[17][t]),

V[t]== Dist[t]+L[t],R== L[t]/Dist[t],Dist[t]+B[t]-H( Sum[kf[i][t] rate[i][t],{i,6,11}])== Fa,s== V[t]/B[t],

Table[{1== y1[i][t]+y2[i][t]+y3[i][t]},{i,0,17}],

Table[{x1[i][0]==0,x2[i][0]==0},{i,0,17}],

Table[T[i][0]==426,{i,0,17}],L[0]==  (((Fa) R s)/(1+R+s)),Table[Le[i][0]==Fa+  (((Fa) R s)/(1+R+s)),{i,1,6}],Dist[0]==  (((Fa) s)/(1+R+s)),B[0]==  (((Fa)+(Fa) R)/(1+R+s)),V[0]== (((Fa) s+(Fa) R s)/(1+R+s))}],

Flatten[{Table[{x1[i][t],x2[i][t],T[i][t]},{i,0,17}],V[t],L[t],Table[Le[i][t],{i,1,6}],B[t],Dist[t]}],{t,0,2000}]];
Switch[ctrl,
1,
ListPlot[{Table[{i,First[x1[i][t]/.sol/.t-> 1500]},{i,0,17}],Table[{i,First[x2[i][t]/.sol/.t-> 1500]},{i,0,17}],Table[{i,First[x3[i][t]/.sol/.t-> 1500]},{i,0,17}]},GridLines-> {Table[i,{i,1,17,1}],Table[i,{i,0,1,0.1}]},ImageSize-> {500,300},Joined-> True,PlotRange-> {{0,17},{-0.1,1.1}},PlotStyle-> {{Thick,RGBColor[.49,0,0]},{Thick,RGBColor[.25,.43,.82]},{Thick,RGBColor[.6,.73,.36]},{Thick,RGBColor[.48,.11,.56]}},Frame-> True,ImageSize-> {500,300},FrameLabel-> {"stage number","liquid composition"}],
2,
Plot[{x1[0][t]/.sol,x2[0][t]/.sol,x3[0][t]/.sol},{t,0,500},Frame-> True,FrameLabel-> {"time","distillate composition"},GridLines-> Automatic,PlotStyle-> Thick,ImageSize-> {500,300} ,PlotRange-> {-0.1,1.1}],
3,
Plot[{x1[17][t]/.sol,x2[17][t]/.sol,x3[17][t]/.sol},{t,0,300},Frame-> True,FrameLabel-> {"time","bottom composition"},GridLines-> Automatic,PlotStyle-> Thick,ImageSize-> {500,300} ,PlotRange-> {-0.1,1.1}]]],{{H,500,"molar hold up in kmol"},{0,20,50,100,250,350,500}},{{ctrl,1,""},{1-> "steady state",2-> "distillate",3-> "bottom"}},
TrackedSymbols:>{H,ctrl},SynchronousUpdating->False]

CAPTION

This Demonstration simulates a reactive distillation column that produces iso-butene and methanol from the decomposition of methyl tert-butyl ether (MTBE). The reaction is MTBE ⇌ iso-butene + methanol. The column is fed with pure MTBE at stage 8. The reactive stages range from 6 to 11. The column has 16 stages, a partial reboiler, and a total condenser. For low Damköhler numbers (with molar hold-up equaling zero), methanol and iso-butene are not formed and the only species present in the column is MTBE. At high Damköhler numbers, we get almost pure methanol as a bottom and pure iso-butene as a distillate.

DETAILS

K. Huang and S. J.  Wang, "Design and Control of a Methyl Tertiary Butyl Ether (MTBE) Decomposition Reactive Distillation Column," Ind. Eng. Chem. Res., 46(8), 2007 pp. 2508–2519.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Methyl Tert-Butyl Ether (MTBE) Decomposition with a Reactive Distillation Unit" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/MethylTertButylEtherMTBEDecompositionWithAReactiveDistillati/

Contributed by: Housam Binous, Manel Selmi, Ines Wada, Selima Allouche, and Ahmed Bellagi

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »